List the winners per day

This query retrieves the winners of contracts published on November 4, 2024, filtered and sorted to meet specific criteria.

Output

  • Publication Number: The unique identifier for the notice.

  • Winner Legal Name: The name of the winning organisation.

  • Amount and currency: The financial offer value and its corresponding currency.

Filters Applied

  • Publication Date: Filters results to contracts published on 2024-11-04.

  • Currency: Restricts the results to contracts involving transactions in Euros (EUR).

  • Winner Status: Selects only tenders with winning status.

  • Sorting: Orders the results by contract amount in descending order.

Query

The complete query in SPARQL is as follows:

PREFIX dc: <http://purl.org/dc/elements/1.1/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX epo: <http://data.europa.eu/a4g/ontology#>
PREFIX cccev: <http://data.europa.eu/m8g/>
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>

SELECT ?publicationNumber ?winnerLegalName  ?amount ?currency WHERE {

  FILTER (?publicationDate = "2024-11-04"^^xsd:date )
  FILTER (?currencyUri = <http://publications.europa.eu/resource/authority/currency/EUR> )
  FILTER (?rank = 1 )
  FILTER (?awardStatusUri = <http://publications.europa.eu/resource/authority/winner-selection-status/selec-w> )  # was selected

  	?noticeUri a epo:Notice ;
  		epo:hasPublicationDate ?publicationDate ;
	  	epo:hasNoticePublicationNumber ?publicationNumber ;
    	epo:announcesAwardDecision [
      		a epo:AwardDecision ;
    		epo:comprisesAwardOutcome [
    			a epo:LotAwardOutcome ;
      			epo:hasAwardStatus ?awardStatusUri ;
         		epo:concernsLot ?lotUri ;
                epo:comprisesTenderAwardOutcome [
          			a epo:TenderAwardOutcome ;
                	epo:hasAwardRank ?rank ;
                    epo:concernsTender [
                        a epo:Tender ;
                        epo:isSubmitedBy [
                              a epo:Tenderer ;
                              epo:playedBy ?winnerUri
                            ] ;
                        epo:hasFinancialOfferValue [
                            a epo:MonetaryValue ;
                            epo:hasAmountValue ?amount ;
                            epo:hasCurrency ?currencyUri ;

                        ]
                    ] ;
      			]
  			]
  		] .

  ?winnerUri epo:hasLegalName ?winnerLegalName .
  ?currencyUri dc:identifier ?currency .

} ORDER BY DESC(?amount)
sparql

Structures Applied

Award Decisions and Outcomes

The query uses a nested structure to retrieve award decisions and their outcomes:

?noticeUri epo:announcesAwardDecision [
           a epo:AwardDecision ;
           epo:comprisesAwardOutcome [
              a epo:LotAwardOutcome ;
              epo:hasAwardStatus ?awardStatusUri ;
               epo:concernsLot ?lotUri ;
                ...
          ]
sparql

Tenderer and Financial Information

The structure links tenderers, tenders, and their financial details:

epo:comprisesTenderAwardOutcome [
  a epo:TenderAwardOutcome ;
  epo:hasAwardRank ?rank ;
  epo:concernsTender [
    a epo:Tender ;
    epo:isSubmitedBy [
      a epo:Tenderer ;
      epo:playedBy ?winnerUri
    ] ;
    epo:hasFinancialOfferValue [
      a epo:MonetaryValue ;
      epo:hasAmountValue ?amount ;
      epo:hasCurrency ?currencyUri
    ]
  ]
sparql

The query retrieves the legal names of the tender:

?winnerUri epo:hasLegalName ?winnerLegalName
sparql

Summary

This query retrieves information about the winners of contracts published on a specific date. The results include details such as publication number, winner’s legal name, financial amounts, and currencies, focusing on first-ranked (winning) tenders.


Any comments on the documentation?