List the named graphs published on a specified period

PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX epo: <http://data.europa.eu/a4g/ontology#>
PREFIX cdm: <http://publications.europa.eu/ontology/cdm#>

SELECT ?date ?journalNumber ?metsNamedGraph ?noticeNamedGraph ?accessUrl ?xmlSource
WHERE {

  FILTER (?date >= "2024-11-04T00:00:00"^^xsd:dateTime &&
          ?date <= "2024-11-05T23:59:59"^^xsd:dateTime)

  GRAPH ?metsNamedGraph {
    ?s a cdm:procurement_public .
    ?s cdm:procurement_public_number_document_in_official-journal ?journalNumber .
    ?s cdm:work_date_document ?date .

    # Construct the target URI based on date and journal number
    BIND(IRI(CONCAT(
               "http://data.europa.eu/a4g/resource/",
               STR(YEAR(xsd:dateTime(?date))), "/",
               ?journalNumber, "_",
               STR(YEAR(xsd:dateTime(?date)))
            )) AS ?noticeNamedGraph)

    BIND(IRI(CONCAT(
               "https://ted.europa.eu/en/notice/-/detail/",
               ?journalNumber, "-",
               STR(YEAR(xsd:dateTime(?date)))
            )) AS ?accessUrl)

    BIND(IRI(CONCAT(
               "https://ted.europa.eu/en/notice/",
               ?journalNumber, "-",
               STR(YEAR(xsd:dateTime(?date))), "/xml"
            )) AS ?xmlSource)
  }
}
sparqlCopied!